#Name: AppliedEnergistics2.zs
#Author: Feed the Beast and Sunekaer

print("Initializing 'AppliedEnergistics2.zs'...");

//import mods.appliedenergistics2.Grinder;

//Recipe conflict
recipes.removeShapeless(<appliedenergistics2:material:3> * 2, [<ore:oreQuartz>, <ore:dustPetrotheum>]);
mods.jei.JEI.removeAndHide(<appliedenergistics2:material:40>);

recipes.addShaped(<appliedenergistics2:facade>.withTag({damage: 0, item: "minecraft:glass"}), [
  [null, <appliedenergistics2:part:120>, null],
  [<appliedenergistics2:part:120>, <minecraft:glass>, <appliedenergistics2:part:120>],
  [null, <appliedenergistics2:part:120>, null]
]);

mods.thermalexpansion.InductionSmelter.addRecipe(<appliedenergistics2:material:15>, <thermalfoundation:storage_alloy:2>, <minecraft:gold_ingot>, 1500);
mods.thermalexpansion.InductionSmelter.addRecipe(<appliedenergistics2:material:14>, <thermalfoundation:storage_alloy:2>, <minecraft:diamond>, 1500);
mods.thermalexpansion.InductionSmelter.addRecipe(<appliedenergistics2:material:13>, <thermalfoundation:storage_alloy:2>, <appliedenergistics2:material>, 1500);
mods.thermalexpansion.InductionSmelter.addRecipe(<appliedenergistics2:material:19>, <thermalfoundation:storage_alloy:2>, <appliedenergistics2:material:5>, 1500);
mods.thermalexpansion.InductionSmelter.addRecipe(<appliedenergistics2:material:19>, <thermalfoundation:storage_alloy:2>, <enderio:item_material:5>, 1500);

mods.extrautils2.Crusher.add(<appliedenergistics2:material:2>, <appliedenergistics2:material>);
mods.extrautils2.Crusher.add(<appliedenergistics2:material:3>, <minecraft:quartz>);
mods.extrautils2.Crusher.add(<appliedenergistics2:material:8>, <appliedenergistics2:material:7>);
mods.extrautils2.Crusher.add(<appliedenergistics2:material:46>, <minecraft:ender_pearl>);

//grinder not accepting wheat, even tho the recipe shows in jei
mods.appliedenergistics2.Grinder.removeRecipe(<minecraft:wheat>);
mods.appliedenergistics2.Grinder.addRecipe(<appliedenergistics2:material:4>, <minecraft:wheat>, 4);
mods.appliedenergistics2.Grinder.addRecipe(<actuallyadditions:item_misc:5>, <actuallyadditions:block_misc:3> ,4);

# Fix Pure Certus in Insolator
recipes.removeByRecipeName("appliedenergistics2:misc/seeds_certus");
recipes.removeByRecipeName("appliedenergistics2:misc/seeds_nether");
recipes.removeByRecipeName("appliedenergistics2:misc/seeds_fluix");

recipes.addShapeless(<appliedenergistics2:crystal_seed>.withTag({progress: 0})*2,
	[<ore:sand>, <ore:dustCertusQuartz>]
);
recipes.addShapeless(<appliedenergistics2:crystal_seed:600>.withTag({progress: 600})*2,
	[<ore:sand>, <appliedenergistics2:material:3>]
);
recipes.addShapeless(<appliedenergistics2:crystal_seed:1200>.withTag({progress: 1200})*2,
	[<ore:sand>, <ore:dustFluix>]
);


mods.thermalexpansion.Insolator.removeRecipe(<appliedenergistics2:crystal_seed:0>, <minecraft:glowstone_dust>);
mods.thermalexpansion.Insolator.removeRecipe(<appliedenergistics2:crystal_seed:600>, <minecraft:glowstone_dust>);
mods.thermalexpansion.Insolator.removeRecipe(<appliedenergistics2:crystal_seed:1200>, <minecraft:glowstone_dust>);


mods.thermalexpansion.Insolator.addRecipe(<appliedenergistics2:material:10>, <appliedenergistics2:crystal_seed:0>.withTag({progress: 0}), <minecraft:glowstone_dust>, 1500, null, 0, 3000);
mods.thermalexpansion.Insolator.addRecipe(<appliedenergistics2:material:11>, <appliedenergistics2:crystal_seed:600>.withTag({progress: 600}), <minecraft:glowstone_dust>, 1500, null, 0, 3000);
mods.thermalexpansion.Insolator.addRecipe(<appliedenergistics2:material:12>, <appliedenergistics2:crystal_seed:1200>.withTag({progress: 1200}), <minecraft:glowstone_dust>, 1500, null, 0, 3000);


print("Initialized 'AppliedEnergistics2.zs'");