// --- Created by DreamMasterXXL ---



// --- Importing Stuff ---


import mods.gregtech.CuttingSaw;
import mods.gregtech.PrecisionLaser;




// --- Variables ---



// --- Removing Recipes ---



// --- Thaumometer
recipes.remove(<Thaumcraft:ItemThaumometer>);

// --- Goggles of Revealing
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemGoggles>);

// --- Table
recipes.remove(<Thaumcraft:blockTable>);

// --- Primal Charm
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemResource:15>);

// --- Mundane Amulet
recipes.remove(<Thaumcraft:ItemBaubleBlanks>);

// --- Mundane Ring
recipes.remove(<Thaumcraft:ItemBaubleBlanks:1>);

// --- Mundane Belt
recipes.remove(<Thaumcraft:ItemBaubleBlanks:2>);

// --- Mirrored Glass
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemResource:10>);

// --- Arcane Stone
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockCosmeticSolid:6>);

// --- Arcan Stone Bricks
recipes.remove(<Thaumcraft:blockCosmeticSolid:7>);

// --- Paving Stone of Travel
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockCosmeticSolid:2>);

// --- Paving Stone of Warding
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockCosmeticSolid:3>);

// --- Runic Matrix
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockStoneDevice:2>);

// --- Arcane Pedstal
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockStoneDevice:1>);

// --- Item Grate
recipes.remove(<Thaumcraft:blockMetalDevice:5>);

// --- Enchanted Fabric
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemResource:7>);

// --- Thaumaturges Robe
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemChestplateRobe>);

// --- Thaumaturges Leggings
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemLeggingsRobe>);

// --- Thaumaturges Boots
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemBootsRobe>);

// --- Arcane Lamp
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockMetalDevice:7>);

// --- Lamp of Growth
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockMetalDevice:8>);

// --- Lamp of Fertility
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockMetalDevice:13>);

// --- Arcane Levitator
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockLifter>);

// --- Arcane Door
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemArcaneDoor>);

// --- Arcane Pressure Plate
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockWoodenDevice:2>);

// --- Warded Glass
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockCosmeticOpaque:2>);

// --- Iron Arcane Key
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ArcaneDoorKey>);

// --- Gold Arcane Key
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ArcaneDoorKey:1>);

// --- Arcane Ear
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockWoodenDevice:1>);

// --- Sinister Load Stone
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemCompassStone>);

// --- Arcane Bellow
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockWoodenDevice>);

// --- Flux Scubber
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockStoneDevice:14>);

// --- Boots of the Traveller
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:BootsTraveller>);

// --- Amulet of Runic Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemAmuletRunic>);

// --- Amulet of Emergency Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemAmuletRunic:1>);

// --- Ring of Runic Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemRingRunic:1>);

// --- Charged Ring of Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemRingRunic:2>);

// --- Revitalizing Ring of Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemRingRunic:3>);

// --- Girdle of Runic Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemGirdleRunic>);

// --- Kinetic Girdle of Shielding
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemGirdleRunic:1>);

// --- Arcan Bore Base
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:blockWoodenDevice:4>);

// --- Arcan Bore
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockWoodenDevice:5>);

// --- Pickaxe of the Core
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemPickaxeElemental>);

// --- Axe of the Stream
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemAxeElemental>);

// --- Sword of Zephyr
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemSwordElemental>);

// --- Shovel of the Earthmover
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemShovelElemental>);

// --- Hoe of Growth
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemHoeElemental>);

// --- Thaumostatic Harness
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:HoverHarness>);

// --- Thauostatic Girdle
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemGirdleHover>);

// --- Magic Mirrored
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockMirror>);

// --- Magic Hand Mirrored
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:HandMirror>);

// --- Essentia Mirrored
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockMirror:6>);

// --- Brain in a Jar
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:blockJar:1>);

// --- Thaumium Fortress Helm
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemHelmetFortress>);

// --- Thaumium Fortress Cuirass
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemChestplateFortress>);

// --- Thaumium Fortress Tigh Guards
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemLeggingsFortress>);

// --- Bone Bow
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemBowBone>);

// --- Scribing Tool
recipes.removeShapeless(<Thaumcraft:ItemInkwell>, [<minecraft:glass_bottle>, <minecraft:feather>, <ore:dyeBlack>]);

// --- Arcane Stone Slabs
recipes.remove(<Thaumcraft:blockCosmeticSlabStone>);





// --- Adding Recipes ---



// --- Scribing Tool
recipes.addShapeless(<Thaumcraft:ItemInkwell>, [<Thaumcraft:ItemEssence>, <minecraft:feather>, <ore:dyeBlack>]);


// --- Thaumometer
recipes.addShaped(<Thaumcraft:ItemThaumometer>, [
[<Thaumcraft:ItemShard>, <Thaumcraft:ItemShard:1>, <Thaumcraft:ItemShard:2>],
[<ore:itemCasingGold>, <ore:lensDiamond>, <ore:itemCasingGold>],
[<Thaumcraft:ItemShard:3>, <Thaumcraft:ItemShard:4>, <Thaumcraft:ItemShard:5>]]);

mods.thaumcraft.Research.clearPages("RESEARCH");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.1");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.2");
mods.thaumcraft.Research.addCraftingPage("RESEARCH", <Thaumcraft:ItemThaumometer>);
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.3");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.4");
mods.thaumcraft.Research.addCraftingPage("RESEARCH", <Thaumcraft:ItemInkwell>);
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.5");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.6");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.7");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.8");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.9");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.10");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.11");
mods.thaumcraft.Research.addPage("RESEARCH", "tc.research_page.RESEARCH.12");

// --- Goggle of Revealing
mods.thaumcraft.Arcane.addShaped("GOGGLES", <Thaumcraft:ItemGoggles> , "aer 30, terra 30, ignis 30, aqua 30, ordo 30, perditio 30" ,[
[<harvestcraft:hardenedleatherItem>, <ore:screwGold>, <harvestcraft:hardenedleatherItem>],
[<ore:ringGold>, <ore:craftingToolScrewdriver>, <ore:ringGold>],
[<Thaumcraft:ItemThaumometer>, <ore:stickGold>, <Thaumcraft:ItemThaumometer>]]);

mods.thaumcraft.Research.setAspects("GOGGLES", "auram 3, praecantatio 9, sensus 9, instrumentum 6");
mods.thaumcraft.Research.setComplexity("GOGGLES", 2);

// --- Table
recipes.addShaped(<Thaumcraft:blockTable>, [
[<ore:slabWood>, <ore:slabWood>, <ore:slabWood>],
[<ore:stickWood>, <ore:screwAnyIron>, <ore:stickWood>],
[<ore:slabWood>, <ore:craftingToolScrewdriver>, <ore:slabWood>]]);

// --- Primal Charm
mods.thaumcraft.Research.clearPages("BASICARTIFACE");
mods.thaumcraft.Research.addPage("BASICARTIFACE", "tc.research_page.BASICARTIFACE.1");
mods.thaumcraft.Arcane.addShaped("BASICARTIFACE", <Thaumcraft:ItemResource:15>, "aer 50, terra 50, ignis 50, aqua 50, ordo 50, perditio 50", [
[<Thaumcraft:blockCrystal>, <Thaumcraft:blockCrystal:1>, <Thaumcraft:blockCrystal:2>],
[<gregtech:gt.metaitem.01:28351>, <Thaumcraft:blockCrystal:6>, <gregtech:gt.metaitem.01:28351>],
[<Thaumcraft:blockCrystal:3>, <Thaumcraft:blockCrystal:4>, <Thaumcraft:blockCrystal:5>]]);
mods.thaumcraft.Research.addArcanePage("BASICARTIFACE", <Thaumcraft:ItemResource:15>);

// --- Mundane Amulet
mods.thaumcraft.Arcane.addShaped("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks>, "terra 5, ignis 10, ordo 10", [
[<ore:wireFineGold>, <ore:wireFineGold>, <ore:wireFineGold>],
[<ore:wireFineGold>, <ore:craftingToolScrewdriver>, <ore:wireFineGold>],
[<ore:screwGold>, <Thaumcraft:blockCrystal:6>, <ore:screwGold>]]);
mods.thaumcraft.Research.addArcanePage("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks>);

// --- Mundane Ring
mods.thaumcraft.Arcane.addShaped("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks:1>, "terra 10, ignis 10, ordo 5", [
[<ore:screwGold>, <ore:stickGold>, <ore:screwGold>],
[<ore:stickGold>, <ore:craftingToolScrewdriver>, <ore:stickGold>],
[<ore:screwGold>, <ore:stickGold>, <ore:screwGold>]]);
mods.thaumcraft.Research.addArcanePage("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks:1>);

// --- Mundane Belt
mods.thaumcraft.Arcane.addShaped("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks:2>, "terra 10, ignis 5, ordo 10", [
[<ore:screwGold>, <ore:materialHardenedleather>, <ore:screwGold>],
[<ore:materialHardenedleather>, <ore:craftingToolScrewdriver>, <ore:materialHardenedleather>],
[<ore:screwGold>, <ore:ringGold>, <ore:screwGold>]]);
mods.thaumcraft.Research.addArcanePage("BASICARTIFACE", <Thaumcraft:ItemBaubleBlanks:2>);

// --- Mirrored Glass
mods.thaumcraft.Arcane.addShaped("BASICARTIFACE", <Thaumcraft:ItemResource:10>, "aer 30, terra 30, ignis 30,", [
[<IC2:itemFluidCell>.withTag({Fluid: {FluidName: "ender", Amount: 1000}}), <ore:gemMercury>, <IC2:itemFluidCell>.withTag({Fluid: {FluidName: "ender", Amount: 1000}})],
[<ore:gemMercury>, <minecraft:glass_pane>, <ore:gemMercury>],
[<IC2:itemFluidCell>.withTag({Fluid: {FluidName: "ender", Amount: 1000}}), <ore:gemMercury>, <IC2:itemFluidCell>.withTag({Fluid: {FluidName: "ender", Amount: 1000}})]]);
mods.thaumcraft.Research.addArcanePage("BASICARTIFACE", <Thaumcraft:ItemResource:10>);

// --- Arcane Stone
mods.thaumcraft.Arcane.addShaped("ARCANESTONE", <Thaumcraft:blockCosmeticSolid:6> * 8, "aer 8, terra 8, ignis 8, aqua 8, ordo 8, perditio 8", [
[<ore:stone>, <ore:stone>, <ore:stone>],
[<ore:stone>, <Thaumcraft:blockCrystal:*>, <ore:stone>],
[<ore:stone>, <ore:stone>, <ore:stone>]]);
// -
recipes.addShapeless(<Thaumcraft:blockCosmeticSlabStone> * 2, [<Thaumcraft:blockCosmeticSolid:7>, <ore:craftingToolSaw>]);
// -
mods.thaumcraft.Research.clearPages("ARCANESTONE");
mods.thaumcraft.Research.addPage("ARCANESTONE", "tc.research_page.ARCANESTONE.1");
mods.thaumcraft.Research.addArcanePage("ARCANESTONE", <Thaumcraft:blockCosmeticSolid:6>);
mods.thaumcraft.Research.addCraftingPage("ARCANESTONE", <Thaumcraft:blockStairsArcaneStone>);
mods.thaumcraft.Research.addCraftingPage("ARCANESTONE", <Thaumcraft:blockCosmeticSlabStone>);

// --- Runic Matrix
mods.thaumcraft.Arcane.addShaped("INFUSION", <Thaumcraft:blockStoneDevice:2> , "aer 40, terra 40, ignis 40, aqua 40, ordo 40, perditio 40" ,[
[<Thaumcraft:blockCosmeticSolid:7>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCosmeticSolid:7>],
[<Thaumcraft:blockCrystal:6>, <minecraft:ender_eye>, <Thaumcraft:blockCrystal:6>],
[<Thaumcraft:blockCosmeticSolid:7>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCosmeticSolid:7>]]);

// --- Arcane Pedstal
mods.thaumcraft.Arcane.addShaped("INFUSION", <Thaumcraft:blockStoneDevice:1> , "aer 20" ,[
[<Thaumcraft:blockCosmeticSolid:6>, <Thaumcraft:blockCosmeticSolid:6>, <Thaumcraft:blockCosmeticSolid:6>],
[null, <Thaumcraft:blockCosmeticSolid:6>, null],
[<Thaumcraft:blockCosmeticSolid:6>, <Thaumcraft:blockCosmeticSolid:6>, <Thaumcraft:blockCosmeticSolid:6>]]);
// -
mods.thaumcraft.Research.setAspects("INFUSION", "fabrico 9, machina 9, praecantatio 6, cognitio 6, motus 3");
mods.thaumcraft.Research.setComplexity("INFUSION", 2);

// --- Paving Stone of Travel
mods.thaumcraft.Research.clearPages("PAVETRAVEL");
mods.thaumcraft.Research.addPage("PAVETRAVEL", "tc.research_page.PAVETRAVEL.1");
mods.thaumcraft.Arcane.addShaped("PAVETRAVEL", <Thaumcraft:blockCosmeticSolid:2> * 4, "aer 12, ordo 12, terra 12", [
[<ore:plateInfusedAir>, <ore:plateInfusedEarth>, <ore:plateInfusedAir>],
[<ore:plateInfusedEarth>, <Thaumcraft:blockCosmeticSolid:7>, <ore:plateInfusedEarth>],
[<ore:plateInfusedAir>, <ore:plateInfusedEarth>, <ore:plateInfusedAir>]]);
mods.thaumcraft.Research.addArcanePage("PAVETRAVEL", <Thaumcraft:blockCosmeticSolid:2>);
// -
mods.thaumcraft.Research.setAspects("PAVETRAVEL", "iter 9, volatus 6, terra 6, motus 3");
mods.thaumcraft.Research.setComplexity("PAVETRAVEL", 2);

// --- Paving Stone of Warding
mods.thaumcraft.Research.clearPages("PAVEWARD");
mods.thaumcraft.Research.addPage("PAVEWARD", "tc.research_page.PAVEWARD.1");
mods.thaumcraft.Arcane.addShaped("PAVEWARD", <Thaumcraft:blockCosmeticSolid:3> * 4, "ignis 12, ordo 12, terra 12", [
[<ore:plateInfusedOrder>, <ore:plateInfusedFire>, <ore:plateInfusedOrder>],
[<ore:plateInfusedFire>, <Thaumcraft:blockCosmeticSolid:7>, <ore:plateInfusedFire>],
[<ore:plateInfusedOrder>, <ore:plateInfusedFire>, <ore:plateInfusedOrder>]]);
mods.thaumcraft.Research.addArcanePage("PAVEWARD", <Thaumcraft:blockCosmeticSolid:3>);
mods.thaumcraft.Research.addPage("PAVEWARD", "tc.research_page.PAVEWARD.2");
// -
mods.thaumcraft.Research.setAspects("PAVEWARD", "motus 6, bestia 9, vinculum 3, telum 6");
mods.thaumcraft.Research.setComplexity("PAVEWARD", 2);

// --- Item Grate
mods.thaumcraft.Research.clearPages("GRATE");
mods.thaumcraft.Research.addPage("GRATE", "tc.research_page.GRATE.1");
mods.thaumcraft.Arcane.addShaped("GRATE", <Thaumcraft:blockMetalDevice:5>, "aer 5, ignis 5, ordo 5", [
[<ore:screwSteel>, <dreamcraft:item.SteelBars>, <ore:screwSteel>],
[<ore:wireGt01RedAlloy>, <dreamcraft:item.AluminiumBars>, <ore:craftingToolScrewdriver>],
[<ore:screwSteel>, <dreamcraft:item.SteelBars>, <ore:screwSteel>]]);
// -
mods.thaumcraft.Research.addArcanePage("GRATE", <Thaumcraft:blockMetalDevice:5>);

// --- Enchanted Fabric
mods.thaumcraft.Research.clearPages("ENCHFABRIC");
mods.thaumcraft.Research.addPage("ENCHFABRIC", "tc.research_page.ENCHFABRIC.1");
mods.thaumcraft.Arcane.addShaped("ENCHFABRIC", <Thaumcraft:ItemResource:7> , "aer 5, terra 5, ignis 5, aqua 5, ordo 5, perditio 5" ,[
[<minecraft:string>, <minecraft:string>, <minecraft:string>],
[<harvestcraft:wovencottonItem>, <harvestcraft:wovencottonItem>, <harvestcraft:wovencottonItem>],
[<minecraft:string>, <minecraft:string>, <minecraft:string>]]);

mods.thaumcraft.Research.setAspects("ENCHFABRIC", "pannus 6, praecantatio 6, tutamen 3");
mods.thaumcraft.Research.setComplexity("ENCHFABRIC", 1);
// -
mods.thaumcraft.Research.addArcanePage("ENCHFABRIC", <Thaumcraft:ItemResource:7>);
mods.thaumcraft.Research.addPage("ENCHFABRIC", "tc.research_page.ENCHFABRIC.2");

// --- Thaumaturges Robe
mods.thaumcraft.Arcane.addShaped("ENCHFABRIC", <Thaumcraft:ItemChestplateRobe> , "aer 15, ignis 15, aqua 15, ordo 15", [
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>],
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>],
[<Thaumcraft:ItemResource:7>, <Thaumcraft:ItemResource:7>, <Thaumcraft:ItemResource:7>]]);
// -
mods.thaumcraft.Research.addArcanePage("ENCHFABRIC", <Thaumcraft:ItemChestplateRobe>);

// --- Thaumaturges Leggings
mods.thaumcraft.Arcane.addShaped("ENCHFABRIC", <Thaumcraft:ItemLeggingsRobe> , "aer 15, ignis 15, aqua 15, perditio 15", [
[<Thaumcraft:ItemResource:7>, <Thaumcraft:ItemResource:7>, <Thaumcraft:ItemResource:7>],
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>],
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>]]);
// -
mods.thaumcraft.Research.addArcanePage("ENCHFABRIC", <Thaumcraft:ItemLeggingsRobe>);

// --- Thaumaturges Boots
mods.thaumcraft.Arcane.addShaped("ENCHFABRIC", <Thaumcraft:ItemBootsRobe> , "aer 15, terra 15, ignis 15, aqua 15", [
[null, null, null],
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>],
[<Thaumcraft:ItemResource:7>, <ore:plateThaumium>, <Thaumcraft:ItemResource:7>]]);
// -
mods.thaumcraft.Research.addArcanePage("ENCHFABRIC", <Thaumcraft:ItemBootsRobe>);

// --- Arcane Lamp
mods.thaumcraft.Arcane.addShaped("ARCANELAMP", <Thaumcraft:blockMetalDevice:7>, "aer 10, perditio 5, ignis 15, aqua 5", [
[<ore:paneGlassColorless>, <minecraft:daylight_detector>, <ore:paneGlassColorless>],
[<ore:plateSteel>, <Thaumcraft:blockCosmeticOpaque>, <ore:plateSteel>],
[<ore:paneGlassColorless>, <Thaumcraft:ItemResource:1>, <ore:paneGlassColorless>]]);
// -
mods.thaumcraft.Research.setAspects("ARCANELAMP", "lux 6, tenebrae 3, sensus 6");
mods.thaumcraft.Research.setComplexity("ARCANELAMP", 1);

// --- Lamp of Growth
mods.thaumcraft.Infusion.addRecipe("LAMPGROWTH", <Thaumcraft:blockMetalDevice:7>, 
[<gregtech:gt.metaitem.01:17086>, <minecraft:dye:15>, <Thaumcraft:blockCrystal:3>, <gregtech:gt.metaitem.01:17086>, <minecraft:dye:15>, <Thaumcraft:blockCrystal:3>], 
"herba 20, lux 10, victus 20, messis 10", <Thaumcraft:blockMetalDevice:8>, 5);
// -
mods.thaumcraft.Research.setAspects("LAMPGROWTH", "messis 9, lux 3, herba 6, victus 9");
mods.thaumcraft.Research.setComplexity("LAMPGROWTH", 2);

// --- Lamp of Fertility
mods.thaumcraft.Infusion.addRecipe("LAMPFERTILITY", <Thaumcraft:blockMetalDevice:7>, 
[<gregtech:gt.metaitem.01:17086>, <minecraft:wheat>, <Thaumcraft:blockCrystal:1>, <gregtech:gt.metaitem.01:17086>, <minecraft:golden_carrot>, <Thaumcraft:blockCrystal:1>], 
"bestia 20, lux 10, victus 20, sano 10", <Thaumcraft:blockMetalDevice:13>, 5);
// -
mods.thaumcraft.Research.setAspects("LAMPFERTILITY", "bestia 9, lux 3, victus 9, sano 6");
mods.thaumcraft.Research.setComplexity("LAMPFERTILITY", 2);

// --- Arcane Levitator
mods.thaumcraft.Arcane.addShaped("LEVITATOR", <Thaumcraft:blockLifter>, "aer 20, terra 10, ordo 5", [
[<Thaumcraft:blockWoodenDevice:6>, <ore:plateInfusedAir>, <Thaumcraft:blockWoodenDevice:6>],
[<Thaumcraft:ItemResource:1>, <ore:rotorThaumium>, <Thaumcraft:ItemResource>],
[<Thaumcraft:blockWoodenDevice:6>, <ore:plateInfusedEarth>, <Thaumcraft:blockWoodenDevice:6>]]);
// -
mods.thaumcraft.Research.setAspects("LEVITATOR", "aer 3, volatus 6, praecantatio 3, motus 6");
mods.thaumcraft.Research.setComplexity("LEVITATOR", 1);

// --- Arcane Door
mods.thaumcraft.Arcane.addShaped("WARDEDARCANA", <Thaumcraft:ItemArcaneDoor>, "terra 15, ignis 5, ordo 20, perditio 10", [
[<Thaumcraft:blockWoodenDevice:6>, <Thaumcraft:ItemZombieBrain>, <ore:craftingToolScrewdriver>],
[<Thaumcraft:blockWoodenDevice:6>, <ore:ringThaumium>, <ore:screwThaumium>],
[<Thaumcraft:blockWoodenDevice:6>, <Thaumcraft:blockWoodenDevice:6>, <ore:craftingToolSaw>]]);
// -
mods.thaumcraft.Research.setAspects("WARDEDARCANA", "tutamen 6, instrumentum 6, machina 6, motus 3");
mods.thaumcraft.Research.setComplexity("WARDEDARCANA", 1);

// --- Arcane Pressure Plate
mods.thaumcraft.Arcane.addShaped("WARDEDARCANA", <Thaumcraft:blockWoodenDevice:2>, "terra 15, ignis 5, ordo 20, perditio 10", [
[<ore:screwThaumium>, <ore:craftingToolScrewdriver>, <ore:screwThaumium>],
[<Thaumcraft:blockCosmeticSlabWood>, <minecraft:heavy_weighted_pressure_plate>, <Thaumcraft:blockCosmeticSlabWood>],
[<ore:plateThaumium>, <Thaumcraft:ItemZombieBrain>, <ore:plateThaumium>]]);

// --- Warded Glass
mods.thaumcraft.Arcane.addShaped("WARDEDARCANA", <Thaumcraft:blockCosmeticOpaque:2> * 4, "aer 10, aqua 10, ignis 10, ordo 10, perditio 10, terra 10", [
[<ore:blockGlass>, <ore:plateThaumium>, <ore:blockGlass>],
[<Thaumcraft:blockWoodenDevice:6>, <Thaumcraft:FocusWarding>, <Thaumcraft:blockWoodenDevice:6>],
[<ore:blockGlass>, <ore:plateThaumium>, <ore:blockGlass>]]);

// --- Iron Arcane Key
mods.thaumcraft.Arcane.addShaped("WARDEDARCANA", <Thaumcraft:ArcaneDoorKey> * 2, "aer 5, ignis 5, ordo 5", [
[<ore:stickIron>, <ore:stickIron>, <ore:ringIron>],
[<ore:boltIron>, <ore:boltIron>, <ore:plateSteel>],
[<ore:boltIron>, <Thaumcraft:ItemResource:1>, null]]);

// --- Gold Arcane Key
mods.thaumcraft.Arcane.addShaped("WARDEDARCANA", <Thaumcraft:ArcaneDoorKey:1> * 2, "aer 10, ignis 10, ordo 10", [
[<ore:stickGold>, <ore:stickGold>, <ore:ringGold>],
[<ore:boltGold>, <ore:boltGold>, <ore:craftingToolScrewdriver>],
[<ore:boltGold>, <ore:craftingToolHardHammer>, null]]);

// --- Arcane Ear
mods.thaumcraft.Arcane.addShaped("ARCANEEAR", <Thaumcraft:blockWoodenDevice:1>, "aer 10, terra 10, ordo 10", [
[<ore:plateThaumium>, <gregtech:gt.metaitem.01:32690>, <ore:plateThaumium>],
[<ore:plateGold>, <Thaumcraft:ItemZombieBrain>, <ore:plateGold>],
[<Thaumcraft:blockWoodenDevice:6>, <ore:wireGt01RedAlloy>, <Thaumcraft:blockWoodenDevice:6>]]);
// -
mods.thaumcraft.Research.setAspects("ARCANEEAR", "aer 9, sensus 9, praecantatio 3, potentia 6");
mods.thaumcraft.Research.setComplexity("ARCANEEAR", 2);

// --- Sinister Load Stone
mods.thaumcraft.Infusion.addRecipe("SINSTONE", <minecraft:flint>, 
[<Thaumcraft:ItemResource:1>, <Thaumcraft:ItemShard:4>, <Thaumcraft:ItemResource:9>, <Thaumcraft:ItemShard:5>, <Thaumcraft:ItemResource>, <Thaumcraft:ItemShard:6>],
 "alienis 10, auram 10, sensus 10, tenebrae 10, ordo 10", <Thaumcraft:ItemCompassStone>, 4);
// -
mods.thaumcraft.Research.setAspects("SINSTONE", "auram 6, sensus 3, tenebrae 6, alienis 6");
mods.thaumcraft.Research.setComplexity("SINSTONE", 2);
mods.thaumcraft.Warp.addToResearch("SINSTONE", 1);

// --- Arcane Bellow
mods.thaumcraft.Arcane.addShaped("BELLOWS", <Thaumcraft:blockWoodenDevice>, "aer 10, ordo 10", [
[<Thaumcraft:blockCosmeticSlabWood>, <ore:shardAir>, <Thaumcraft:blockCosmeticSlabWood>],
[<Backpack:tannedLeather>, <gregtech:gt.metaitem.01:32640>, <Backpack:tannedLeather>],
[<Thaumcraft:blockCosmeticSlabWood>, <ore:shardAir>, <Thaumcraft:blockCosmeticSlabWood>]]);
// -
mods.thaumcraft.Research.setAspects("BELLOWS", "motus 6, aer 12, praecantatio 3, machina 9");
mods.thaumcraft.Research.setComplexity("BELLOWS", 2);

// --- Flux Scubber
mods.thaumcraft.Research.clearPages("FLUXSCRUB");
mods.thaumcraft.Research.addPage("FLUXSCRUB", "tc.research_page.FLUXSCRUB.1");
mods.thaumcraft.Infusion.addRecipe("FLUXSCRUB", <Thaumcraft:blockWoodenDevice>, 
[<Thaumcraft:blockTube>, <dreamcraft:item.SteelBars>, <Thaumcraft:ItemResource:8>, <Thaumcraft:blockCosmeticSolid:7>, <Thaumcraft:blockTube:1>, <Thaumcraft:blockCosmeticSolid:7>, <Thaumcraft:ItemResource:8>, <dreamcraft:item.SteelBars>], 
"aqua 25, aer 20, praecantatio 15, vinculum 10, vitium 5", <Thaumcraft:blockStoneDevice:14>, 4);
mods.thaumcraft.Research.addInfusionPage("FLUXSCRUB", <Thaumcraft:blockStoneDevice:14>);
// -
mods.thaumcraft.Research.setAspects("FLUXSCRUB", "aqua 15, praecantatio 12, aer 9, vinculum 6, vitium 3");
mods.thaumcraft.Research.setComplexity("FLUXSCRUB", 3);

// --- Boots of the Traveller
mods.thaumcraft.Infusion.addRecipe("BOOTSTRAVELLER", <minecraft:leather_boots>, 
[<Thaumcraft:blockCrystal>, <Thaumcraft:ItemResource:7>, <minecraft:feather>, <Thaumcraft:ItemResource:7>, <Thaumcraft:blockCrystal>, <Thaumcraft:ItemResource:7>, <minecraft:fish:*>, <Thaumcraft:ItemResource:7>], 
"volatus 25, aer 25, iter 25, aqua 5", <Thaumcraft:BootsTraveller>, 2);
// -
mods.thaumcraft.Research.setAspects("BOOTSTRAVELLER", "aqua 9, iter 15, terra 6, volatus 12, aer 3");
mods.thaumcraft.Research.setComplexity("BOOTSTRAVELLER", 3);

// --- Ring of Runic Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICARMOR", <Thaumcraft:ItemBaubleBlanks:1>, 
[<Thaumcraft:ItemResource:15>, <gregtech:gt.metaitem.02:29514>, <Thaumcraft:ItemResource:7>, <Thaumcraft:ItemInkwell>, <minecraft:blaze_powder>, <gregtech:gt.metaitem.02:29514>], 
"potentia 25, tutamen 25, praecantatio 25, alienis 5", <Thaumcraft:ItemRingRunic:1>, 2);
// -
mods.thaumcraft.Research.setAspects("RUNICARMOR", "cognitio 15, tutamen 12, aer 9, potentia 9, praecantatio 6, alienis 3");
mods.thaumcraft.Research.setComplexity("RUNICARMOR", 3);

// --- Charged Ring of Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICCHARGED", <Thaumcraft:ItemRingRunic:1>,
[<minecraft:potion:8226>, <Thaumcraft:blockCrystal:1>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:1>, <minecraft:potion:8226>, <Thaumcraft:blockCrystal:1>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:1>],
"potentia 64, tutamen 32, praecantatio 32, alienis 16, aer 8", <Thaumcraft:ItemRingRunic:2>, 6);
// -
mods.thaumcraft.Research.setAspects("RUNICCHARGED", "praecantatio 15, potentia 12, tutamen 9, alienis 12, aer 9, cognitio 6, terra 3");
mods.thaumcraft.Research.setComplexity("RUNICCHARGED", 3);

// --- Revitalizing Ring of Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICHEALING", <Thaumcraft:ItemRingRunic:1>,
[<minecraft:potion:8225>, <Thaumcraft:blockCrystal:2>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:2>, <minecraft:potion:8225>, <Thaumcraft:blockCrystal:2>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:2>],
"aqua 64, praecantatio 32, sano 32, tutamen 32, aer 8", <Thaumcraft:ItemRingRunic:3>, 6);
// -
mods.thaumcraft.Research.setAspects("RUNICHEALING", "praecantatio 18, aqua 15, sano 12, tutamen 9, alienis 9, aer 6, cognitio 3");
mods.thaumcraft.Research.setComplexity("RUNICHEALING", 3);

// --- Amulet of Runic Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICARMOR", <Thaumcraft:ItemBaubleBlanks>, 
[<Thaumcraft:ItemResource:15>, <gregtech:gt.metaitem.02:29514>, <minecraft:blaze_powder>, <Thaumcraft:ItemResource:7>, <Thaumcraft:ItemInkwell>, <Thaumcraft:ItemResource:7>, <minecraft:blaze_powder>, <gregtech:gt.metaitem.02:29514>], 
"potentia 40, tutamen 40, praecantatio 40, alienis 20", <Thaumcraft:ItemAmuletRunic>, 4);

// --- Amulet of Emergency Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICEMERGENCY", <Thaumcraft:ItemAmuletRunic>,
[<minecraft:potion:8233>, <Thaumcraft:blockCrystal:3>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:3>, <minecraft:potion:8233>, <Thaumcraft:blockCrystal:3>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal:3>],
"praecantatio 64, terra 64, tutamen 64, vacuos 32, sano 8", <Thaumcraft:ItemAmuletRunic:1>, 8);
// -
mods.thaumcraft.Research.setAspects("RUNICEMERGENCY", "vacuos 15, praecantatio 12, terra 9, tutamen 9, alienis 6, sano 6, cognitio 3");
mods.thaumcraft.Research.setComplexity("RUNICEMERGENCY", 3);

// --- Girdle of Runic Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICARMOR", <Thaumcraft:ItemBaubleBlanks:2>, 
[<Thaumcraft:ItemResource:15>, <gregtech:gt.metaitem.02:29514>, <Thaumcraft:ItemResource:7>, <minecraft:blaze_powder>, <Thaumcraft:ItemResource:7>, <Thaumcraft:ItemInkwell>, <minecraft:blaze_powder>, <Thaumcraft:ItemResource:7>, <minecraft:blaze_powder>, <gregtech:gt.metaitem.02:29514>], 
"potentia 55, tutamen 55, praecantatio 55, alienis 35", <Thaumcraft:ItemGirdleRunic>, 4);

// --- Kinetic Girdle of Shielding
mods.thaumcraft.Infusion.addRecipe("RUNICKINETIC", <Thaumcraft:ItemGirdleRunic>,
[<minecraft:potion:16428>, <Thaumcraft:blockCrystal>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal>, <minecraft:potion:16428>, <Thaumcraft:blockCrystal>, <Thaumcraft:blockCrystal:6>, <Thaumcraft:blockCrystal>],
"aer 64, praecantatio 64, tutamen 64, bestia 32, telum 8", <Thaumcraft:ItemGirdleRunic:1>, 8);
// -
mods.thaumcraft.Research.setAspects("RUNICKINETIC", "aer 18, praecantatio 15, tutamen 12, telum 9, alienis 9, bestia 6, cognitio 3");
mods.thaumcraft.Research.setComplexity("RUNICKINETIC", 3);

// --- Arcan Bore
mods.thaumcraft.Infusion.addRecipe("ARCANEBORE", <gregtech:gt.metaitem.01:32641>, 
[<Thaumcraft:blockWoodenDevice:6>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:24500>, <Thaumcraft:blockCrystal>, <Thaumcraft:ItemShovelThaumium>, <Thaumcraft:blockWoodenDevice:6>, <gregtech:gt.metaitem.01:17086>, <Thaumcraft:blockCrystal:3>, <gregtech:gt.metaitem.01:24500>, <Thaumcraft:ItemPickThaumium>], 
"machina 64, motus 32, perditio 64, potentia 32, vacuos 32", <Thaumcraft:blockWoodenDevice:5>, 6);
// -
mods.thaumcraft.Research.setAspects("ARCANEBORE", "instrumentum 15, perfodio 12, machina 9, motus 9, vacuos 3, cognitio 6");
mods.thaumcraft.Research.setComplexity("ARCANEBORE", 3);

// --- Arcan Bore Base
mods.thaumcraft.Arcane.addShaped("ARCANEBORE", <Thaumcraft:blockWoodenDevice:4>, "aer 30, ordo 30, terra 30", [
[<Thaumcraft:blockCosmeticSlabWood>, <ore:pipeSmallSteel>, <Thaumcraft:blockCosmeticSlabWood>],
[<ore:plateSteel>, <minecraft:dispenser>, <ore:plateSteel>],
[<Thaumcraft:blockWoodenDevice:6>, <ore:wireFineSteel>, <Thaumcraft:blockWoodenDevice:6>]]);

// --- Pickaxe of the Core
mods.thaumcraft.Infusion.addRecipe("ELEMENTALPICK", <Thaumcraft:ItemPickThaumium>,
[<gregtech:gt.metaitem.02:29502>, <Thaumcraft:blockMagicalLog:1>, <Thaumcraft:blockCrystal:1>, <gregtech:gt.metaitem.02:29500>, <Thaumcraft:blockMagicalLog>, <Thaumcraft:blockCrystal:1>],
"ignis 20, perfodio 20, sensus 20, lucrum 20", <Thaumcraft:ItemPickaxeElemental>, 3);
// -
mods.thaumcraft.Research.setAspects("ELEMENTALPICK", "instrumentum 15, ignis 12, perfodio 9, lucrum 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("ELEMENTALPICK", 3);

// --- Axe of the Stream
mods.thaumcraft.Infusion.addRecipe("ELEMENTALAXE", <Thaumcraft:ItemAxeThaumium>,
[<gregtech:gt.metaitem.02:29503>, <Thaumcraft:blockMagicalLog:1>, <Thaumcraft:blockCrystal:2>, <gregtech:gt.metaitem.02:29500>, <Thaumcraft:blockMagicalLog>, <Thaumcraft:blockCrystal:2>],
"aqua 10, arbor 20, fabrico 20, motus 20", <Thaumcraft:ItemAxeElemental>, 3);
// -
mods.thaumcraft.Research.setAspects("ELEMENTALAXE", "instrumentum 15, motus 12, fabrico 9, aqua 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("ELEMENTALAXE", 3);

// --- Sword of Zephyr
mods.thaumcraft.Infusion.addRecipe("ELEMENTALSWORD", <Thaumcraft:ItemSwordThaumium>,
[<gregtech:gt.metaitem.02:29528>, <Thaumcraft:blockMagicalLog:1>, <Thaumcraft:blockCrystal>, <gregtech:gt.metaitem.02:29500>, <Thaumcraft:blockMagicalLog>, <Thaumcraft:blockCrystal>],
"aer 20, motus 20, potentia 20, telum 20", <Thaumcraft:ItemSwordElemental>, 3);
// -
mods.thaumcraft.Research.setAspects("ELEMENTALSWORD", "instrumentum 15, telum 12, potentia 9, aer 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("ELEMENTALSWORD", 3);

// --- Shovel of the Earthmover
mods.thaumcraft.Infusion.addRecipe("ELEMENTALSHOVEL", <Thaumcraft:ItemShovelThaumium>,
[<gregtech:gt.metaitem.02:29501>, <Thaumcraft:blockMagicalLog:1>, <Thaumcraft:blockCrystal:3>, <gregtech:gt.metaitem.02:29500>, <Thaumcraft:blockMagicalLog>, <Thaumcraft:blockCrystal:3>],
"fabrico 20, terra 20, perfodio 10, praecantatio 20", <Thaumcraft:ItemShovelElemental>, 3);
// -
mods.thaumcraft.Research.setAspects("ELEMENTALSHOVEL", "instrumentum 15, terra 12, perfodio 9, fabrico 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("ELEMENTALSHOVEL", 3);

// --- Hoe of Growth
mods.thaumcraft.Infusion.addRecipe("ELEMENTALHOE", <Thaumcraft:ItemHoeThaumium>,
[<gregtech:gt.metaitem.02:29514>, <Thaumcraft:blockMagicalLog:1>, <Thaumcraft:blockCrystal:5>, <gregtech:gt.metaitem.02:29500>, <Thaumcraft:blockMagicalLog>, <Thaumcraft:blockCrystal:4>],
"meto 10, herba 20, terra 20, messis 20", <Thaumcraft:ItemHoeElemental>, 3);
// -
mods.thaumcraft.Research.setAspects("ELEMENTALHOE", "instrumentum 15, victus 12, meto 9, messis 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("ELEMENTALHOE", 3);

// --- Thaumostatic Harness
mods.thaumcraft.Infusion.addRecipe("HOVERHARNESS", <minecraft:leather_chestplate>, 
[<gregtech:gt.metaitem.01:17330>, <Thaumcraft:blockWoodenDevice:6>, <Thaumcraft:blockCrystal>, <gregtech:gt.metaitem.01:17019>, <gregtech:gt.metaitem.01:17086>, <ProjRed|Integration:projectred.integration.gate:26>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:17019>, <Thaumcraft:blockCrystal>, <Thaumcraft:blockWoodenDevice:6>],
"iter 32, machina 64, potentia 32, volatus 32, tutamen 16", <Thaumcraft:HoverHarness>, 6);
// -
mods.thaumcraft.Research.setAspects("HOVERHARNESS", "volatus 15, machina 12, iter 9, aer 9, praecantatio 6, tutamen 3");
mods.thaumcraft.Research.setComplexity("HOVERHARNESS", 3);

// --- Thaumostatic Girdle
mods.thaumcraft.Infusion.addRecipe("HOVERGIRDLE", <Thaumcraft:ItemBaubleBlanks:2>,
[<Thaumcraft:blockCrystal>, <minecraft:feather>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:17019>, <Thaumcraft:blockCrystal:3>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17019>, <gregtech:gt.metaitem.01:17086>, <TwilightForest:item.tfFeather>],
"aer 64, iter 32, potentia 32, volatus 32, tutamen 16", <Thaumcraft:ItemGirdleHover>, 8);
// -
mods.thaumcraft.Research.setAspects("HOVERGIRDLE", "volatus 15, motus 12, iter 9, aer 9, praecantatio 6, tutamen 3");
mods.thaumcraft.Research.setComplexity("HOVERGIRDLE", 3);

// --- Runic Shielding
mods.thaumcraft.Research.setAspects("RUNICARMOR", "praecantatio 15, lucrum 12, permutatio 9, tutamen 9, cognitio 6, alienis 6, potentia 3");
mods.thaumcraft.Research.setComplexity("RUNICARMOR", 3);

// --- Magic Mirror
mods.thaumcraft.Infusion.addRecipe("MIRROR", <Thaumcraft:ItemResource:10>,
[<gregtech:gt.metaitem.01:17367>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17367>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:27330>],
"iter 32, permutatio 24, tenebrae 16, alienis 8", <Thaumcraft:blockMirror>, 6);
// -
mods.thaumcraft.Research.setAspects("MIRROR", "vitreus 15, iter 12, tenebrae 9, alienis 9, cognitio 6, potentia 3");
mods.thaumcraft.Research.setComplexity("MIRROR", 3);
mods.thaumcraft.Warp.addToResearch("MIRROR", 2);

// --- Magic Hand Mirror
mods.thaumcraft.Infusion.addRecipe("MIRRORHAND", <Thaumcraft:blockMirror>,
[<minecraft:compass>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:27330>, <minecraft:map>, <gregtech:gt.metaitem.01:27330>, <Thaumcraft:WandRod>, <gregtech:gt.metaitem.01:27330>],
"instrumentum 64, iter 32, motus 24, alienis 16, potentia 8", <Thaumcraft:HandMirror>, 9);
// -
mods.thaumcraft.Research.setAspects("MIRRORHAND", "iter 18, instrumentum 15, vitreus 12, alienis 9, cognitio 6, potentia 6, praecantatio 3");
mods.thaumcraft.Research.setComplexity("MIRRORHAND", 3);
mods.thaumcraft.Warp.addToResearch("MIRRORHAND", 3);

// --- Essentia Mirror
mods.thaumcraft.Infusion.addRecipe("MIRRORESSENTIA", <Thaumcraft:ItemResource:10>,
[<gregtech:gt.metaitem.01:17028>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17305>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17028>, <gregtech:gt.metaitem.01:27330>, <gregtech:gt.metaitem.01:17305>, <gregtech:gt.metaitem.01:27330>],
"aqua 24, iter 32, permutatio 16, vitreus 8", <Thaumcraft:blockMirror:6>, 2);
// -
mods.thaumcraft.Research.setAspects("MIRRORESSENTIA", "praecantatio 15, iter 12, vitreus 9, alienis 9, cognitio 6, potentia 6, aqua 3");
mods.thaumcraft.Research.setComplexity("MIRRORESSENTIA", 3);
mods.thaumcraft.Warp.addToResearch("MIRRORESSENTIA", 3);

// --- Brain in a Jar
mods.thaumcraft.Infusion.addRecipe("JARBRAIN", <Thaumcraft:blockJar>, 
[<Thaumcraft:ItemZombieBrain>, <minecraft:poisonous_potato>, <minecraft:spider_eye>, <minecraft:water_bucket>, <minecraft:spider_eye>, <minecraft:poisonous_potato>],
"cognitio 15, exanimis 30, sensus 15, alienis 10", <Thaumcraft:blockJar:1>, 5);
// -
mods.thaumcraft.Research.setAspects("JARBRAIN", "lucrum 15, fames 12, exanimis 9, cognitio 9, alienis 6, potentia 3");
mods.thaumcraft.Research.setComplexity("JARBRAIN", 3);

// --- Infuision Enchantment
mods.thaumcraft.Research.setAspects("INFUSIONENCHANTMENT", "instrumentum 15, praecantatio 15, tutamen 12, cognitio 12, telum 9, potentia 9, alienis 6, potentia 3");
mods.thaumcraft.Research.setComplexity("INFUSIONENCHANTMENT", 4);

// --- Thaumium Fortress Helm
mods.thaumcraft.Infusion.addRecipe("ARMORFORTRESS", <Thaumcraft:ItemHelmetThaumium>,
[<gregtech:gt.metaitem.02:29501>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <harvestcraft:hardenedleatherItem>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17086>],
"metallum 32, praecantatio 32, tutamen 32, victus 16", <Thaumcraft:ItemHelmetFortress>, 4);
// -
mods.thaumcraft.Research.setAspects("ARMORFORTRESS", "fabrico 15, metallum 12, tutamen 9, alienis 9, cognitio 6, potentia 3");
mods.thaumcraft.Research.setComplexity("ARMORFORTRESS", 3);

// --- Thaumium Fortress Cuirass
mods.thaumcraft.Infusion.addRecipe("ARMORFORTRESS", <Thaumcraft:ItemChestplateThaumium>,
[<gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <harvestcraft:hardenedleatherItem>, <gregtech:gt.metaitem.01:17086>, <harvestcraft:hardenedleatherItem>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>],
"metallum 32, praecantatio 32, tutamen 40, cognitio 16", <Thaumcraft:ItemChestplateFortress>, 4);

// --- Thaumium Fortress Tigh Guards
mods.thaumcraft.Infusion.addRecipe("ARMORFORTRESS", <Thaumcraft:ItemLeggingsThaumium>,
[<Thaumcraft:ItemBaubleBlanks:2>, <gregtech:gt.metaitem.01:17086>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <harvestcraft:hardenedleatherItem>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17330>, <gregtech:gt.metaitem.01:17086>],
"metallum 32, praecantatio 32, tutamen 24, terra 16", <Thaumcraft:ItemLeggingsFortress>, 4);

// --- Helm of Revealing
mods.thaumcraft.Research.setAspects("HELMGOGGLES", "tutamen 15, sensus 12, auram 9, alienis 9, praecantatio 6, fabrico 3");
mods.thaumcraft.Research.setComplexity("HELMGOGGLES", 3);

// --- Grinning Devil Faceplate
mods.thaumcraft.Research.setAspects("MASKGRINNINGDEVIL", "tutamen 15, sano 12, cognitio 9, alienis 9, praecantatio 6, fabrico 3");
mods.thaumcraft.Research.setComplexity("MASKGRINNINGDEVIL", 3);
mods.thaumcraft.Warp.addToResearch("MASKGRINNINGDEVIL", 1);

// --- Angry Ghost Faceplate
mods.thaumcraft.Research.setAspects("MASKANGRYGHOST", "tutamen 15, perditio 12, mortuus 9, alienis 9, praecantatio 6, fabrico 3");
mods.thaumcraft.Research.setComplexity("MASKANGRYGHOST", 3);
mods.thaumcraft.Warp.addToResearch("MASKANGRYGHOST", 1);

// --- Sipping Fiend Faceplate
mods.thaumcraft.Research.setAspects("MASKSIPPINGFIEND", "tutamen 15, exanimis 12, victus 9, alienis 9, cognitio 6, potentia 3");
mods.thaumcraft.Research.setComplexity("MASKSIPPINGFIEND", 3);
mods.thaumcraft.Warp.addToResearch("MASKSIPPINGFIEND", 2);

// --- Bone Bow
mods.thaumcraft.Arcane.addShaped("BONEBOW", <Thaumcraft:ItemBowBone>, "aer 32, perditio 32, terra 32", [
[<Natura:barleyFood:7>, <minecraft:bone>, <ore:screwThaumium>],
[<Natura:barleyFood:7>, <Thaumcraft:blockCrystal:5>, <dreamcraft:item.LichBone>],
[<Natura:barleyFood:7>, <minecraft:bone>, <ore:screwThaumium>]]);
// -
mods.thaumcraft.Research.setAspects("BONEBOW", "telum 12, motus 9, aer 6, exanimis 3");
mods.thaumcraft.Research.setComplexity("BONEBOW", 2);




// --- Cutting Saw recipes ---


// --- Arcane Stone Slabs
CuttingSaw.addRecipe(<Thaumcraft:blockCosmeticSlabStone> * 4, null, <Thaumcraft:blockCosmeticSolid:7>, <liquid:water> * 32, 400, 30);
// -
CuttingSaw.addRecipe(<Thaumcraft:blockCosmeticSlabStone> * 4, null, <Thaumcraft:blockCosmeticSolid:7>, <liquid:ic2distilledwater> * 20, 400, 30);
// -
CuttingSaw.addRecipe(<Thaumcraft:blockCosmeticSlabStone> * 4, null, <Thaumcraft:blockCosmeticSolid:7>, <liquid:lubricant> * 8, 200, 30);







// --- Precision Laser Recipes --- 



// --- Arcan Stone Bricks
PrecisionLaser.addRecipe(<Thaumcraft:blockCosmeticSolid:7>, <Thaumcraft:blockCosmeticSolid:6>, <ore:craftingLensRed> * 0, 600, 120);




// --- Refresh Recipese --- 




// --- Thaumometer
mods.thaumcraft.Research.refreshResearchRecipe("THAUMOMETER");

// --- Goggles of Revealing
mods.thaumcraft.Research.refreshResearchRecipe("GOGGLES");

// --- Table
mods.thaumcraft.Research.refreshResearchRecipe("TABLE");

// --- Arcane Stone
mods.thaumcraft.Research.refreshResearchRecipe("ARCANESTONE");

// --- Pedstal and Runic Matrix
mods.thaumcraft.Research.refreshResearchRecipe("INFUSION");

// --- Arcane Lamp
mods.thaumcraft.Research.refreshResearchRecipe("ARCANELAMP");

// --- Lamp of Growth
mods.thaumcraft.Research.refreshResearchRecipe("LAMPGROWTH");

// --- Lamp of Fertility
mods.thaumcraft.Research.refreshResearchRecipe("LAMPFERTILITY");

// --- Paving Stone of Travel
mods.thaumcraft.Research.refreshResearchRecipe("PAVETRAVEL");

// --- Paving Stone of Warding
mods.thaumcraft.Research.refreshResearchRecipe("PAVEWARD");

// --- Arcane Levitator
mods.thaumcraft.Research.refreshResearchRecipe("LEVITATOR");

// --- Arcane Door, Pressure Plate, Keys, Warded Glass
mods.thaumcraft.Research.refreshResearchRecipe("WARDEDARCANA");

// --- Arcane Ear
mods.thaumcraft.Research.refreshResearchRecipe("ARCANEEAR");

// --- Sinister Load Stone
mods.thaumcraft.Research.refreshResearchRecipe("SINSTONE");

// --- Arcane Bellow
mods.thaumcraft.Research.refreshResearchRecipe("BELLOWS");

// --- Flux Scubber
mods.thaumcraft.Research.refreshResearchRecipe("FLUXSCRUB");

// --- Boots of the Traveller
mods.thaumcraft.Research.refreshResearchRecipe("BOOTSTRAVELLER");

// --- Amulet Ring and Girdle of Runic Schielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICARMOR");

// --- Kinetic Girdle of Shielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICKINETIC");

// --- Amulet of Emergency Shielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICEMERGENCY");

// --- Charged Ring of Shielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICCHARGED");

// --- Revitalizing Ring of Shielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICHEALING");

// --- Arcan Bore and Base
mods.thaumcraft.Research.refreshResearchRecipe("ARCANEBORE");

// --- Pickaxe of the Core
mods.thaumcraft.Research.refreshResearchRecipe("ELEMENTALPICK");

// --- Axe of the Stream
mods.thaumcraft.Research.refreshResearchRecipe("ELEMENTALAXE");

// --- Sword of Zephyr
mods.thaumcraft.Research.refreshResearchRecipe("ELEMENTALSWORD");

// --- Shovel of the Earthmover
mods.thaumcraft.Research.refreshResearchRecipe("ELEMENTALSHOVEL");

// --- Hoe of Growth
mods.thaumcraft.Research.refreshResearchRecipe("ELEMENTALHOE");

// --- Thaumostatic Harness
mods.thaumcraft.Research.refreshResearchRecipe("HOVERHARNESS");

// --- Thaumostatic Girdle
mods.thaumcraft.Research.refreshResearchRecipe("HOVERGIRDLE");

// --- Runic Shielding
mods.thaumcraft.Research.refreshResearchRecipe("RUNICARMOR");

// --- Magic Mirror
mods.thaumcraft.Research.refreshResearchRecipe("MIRROR");

// --- Magic Hand Mirror
mods.thaumcraft.Research.refreshResearchRecipe("MIRRORHAND");

// --- Essentia Mirror
mods.thaumcraft.Research.refreshResearchRecipe("MIRRORESSENTIA");

// --- Brain in a Jar
mods.thaumcraft.Research.refreshResearchRecipe("JARBRAIN");

// --- Infuision Enchantment
mods.thaumcraft.Research.refreshResearchRecipe("INFUSIONENCHANTMENT");

// --- Thaumium Fortress Armor
mods.thaumcraft.Research.refreshResearchRecipe("ARMORFORTRESS");

// --- Helm of Revealing
mods.thaumcraft.Research.refreshResearchRecipe("HELMGOGGLES");

// --- Grinning Devil Faceplate
mods.thaumcraft.Research.refreshResearchRecipe("MASKGRINNINGDEVIL");

// --- Angry Ghost Faceplate
mods.thaumcraft.Research.refreshResearchRecipe("MASKANGRYGHOST");

// --- Sipping Fiend Faceplate
mods.thaumcraft.Research.refreshResearchRecipe("MASKSIPPINGFIEND");

// --- Bone Bow
mods.thaumcraft.Research.refreshResearchRecipe("BONEBOW");





// --- Hiding Stuff ---